Re: jak formatovat %DATE% ve W2K

Thirsty <milos.balcar@gmail.com>:


>> potrebuji ted delat nejake zalohy na W2K stroji do extra slozky kazdy
>> den (jen za pomoci cmd)
>> tento samy system pouzivam i na strojich s XP kde je vse v poradku
>> mkdir c:\zalohy\%DATE%
>> %DATE% jako takove je dle MSN ovlivneno kratkym formatem data v
>> mistnim nastaveni - v XP mam nastaveno rrrr-MM-dd
>> a po kontrole v CMD pres echo %DATE% je vse OK
>> v W2K ale po tom samem nastaveni pres echo zobrazi: út 2006-01-31

Formatovat datum nelze, ale lze si z nej pomoci SET precist jen cast a pak
to slepit dohramady podle vlastniho prani. Bohuzel je to vzdy nachylne na
format zobrazeni data, takze to nelze udelat univerzalni zejmena pro vsechny
jazykove verze a pro uzivatelem zmeneny format zobrazeni data.

Tady mas ukazku jak to lze udelat, vychazi ze snadardniho formatu data pod
winXP CZ, datum ma format "st 01.02.2006". Je tam pouzito tzv rozvinuti
promennych, viz help (win+f1, pripadne "help for").

-pp21-


@echo off

set tmpDATE=%DATE%
set tmpTIME=%TIME: =0%

set actualDAY=%tmpDATE:~3,2%
set actualMONTH=%tmpDATE:~6,2%
set actualYEAR2=%tmpDATE:~11,2%
set actualYEAR4=%tmpDATE:~9,4%
set actualHOUR=%tmpTIME:~0,2%
set actualMIN=%tmpTIME:~3,2%
set actualSEC=%tmpTIME:~6,2%

echo.
echo   popis          promenna        obsah
echo   ------------------------------------
echo aktualni datum a cas:
echo   den            actualDAY       %actualDAY%
echo   mesic          actualMONTH     %actualMONTH%
echo   rok (2 cifry)  actualYEAR2     %actualYEAR2%
echo   rok (4 cifry)  actualYEAR4     %actualYEAR4%
echo   hodina         actualHOUR      %actualHOUR%
echo   minuta         actualMIN       %actualMIN%
echo   sekunda        actualSEC       %actualSEC%
echo.
echo Z techto promennych uz si muzete poskladat co chcete,
echo treba prikaz pro prejmenovani souboru:
echo REN log.txt %actualYEAR4%-%actualMONTH%-%actualDAY%_log.txt
echo.