Re: Reset w2k pri absenci pingu

Ivo Cilich <konve@cilich.com>:

> Neznate nekdo nejakou utilitku, ktera by umela sama resetnout
> Win2000, pokud neprojde vice jak (treba) 20 pingu na urcitou IP? Nebo
> radu jak totez nejak jednoduse udelat svepomoci v ramci W2k ...
> Predem moc dik za jakoukoli radu :-)

Kdyz rikas jakoukoliv radu tak ja to zkusim ;o).

Budes k tomu potrebovat wokeni planovac uloh, davkovy soubor a nejaky
program, ktery ti z prikazove radky dokaze resetovat pocitac. Pod w2k jsem
jeden cas pozival tohle:
http://www.budja.com/shutdown/

Funguje to tak, ze se obycejnym prikazem ping posles 20 zadosti o odezvu
(/n 20), vystup se ulozi do souboru MyPings.tmp. V nem se najde radek
Pakety: Odeslané = 20, Přijaté = 20, Ztracené = 0
a ten se ulozi do souboru MyPings2.tmp. Ten soubor se precte, vysledek
se rozdeli po znaku = a ctrvrta cast obsahuje pocet ztracenych paketu.
Pokud jich je 20, spusti se prikaz pro reboot. Soubory *.tmp se smazou.

Musis si tam nastavit nejaky adresar do ktereho ukladat docasne soubory
a pochopitelne IP adresu na kterou posilat pingy ;o))


------------------------------------------------
@echo off
set MyPingPath=C:\temp\

ping /n 20 192.168.0.1 > %MyPingPath%MyPings.tmp
findstr "Pakety: Odeslan" %MyPingPath%MyPings.tmp > %MyPingPath%MyPings2.tmp
for /F "tokens=4 delims==" %%s in (%MyPingPath%MyPings2.tmp) do set PL=%%s

del %MyPingPath%MyPings.tmp
del %MyPingPath%MyPings2.tmp

if %PL% == 20 goto restart

goto end

:restart
echo sem prijde prikaz pro restart

:end
------------------------------------------------

A pokud bys chtel vysledky logovat, pridej si za radky s "del" jeste tohle:
echo %DATE:~3% %TIME:~0,8% %PL% >> %MyPingPath%ping-log.txt


No a pak to musis nejak pavidelne spoustet. Ja pouzivam prikaz AT, sice se
to nastavuje komplikovane, ale je vzdy k dispozici ;o)

AT 0:15 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
AT 0:45 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
AT 1:15 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
AT 1:45 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
AT 2:15 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
AT 2:45 /EVERY:Po,Út,St,Čt,Pá,So,Ne C:\MyPing.bat
...


Hodne steti ;o)

P.S.: Urcite by to slo udelat i bez docasnych souboru pomoci |, ale to
neumim...

-pp21-